on ^1:HOTLINK:*item=*:#:{
  .timerwh off
  .timerwh 1 3 window -c @wowhead
  window -dBdpow0 +dL @wowhead $calc($mouse.dx +15) $calc($mouse.dy -215) 300 200
  if ((http:// isin $1) && (!%cooldown)) || (%lastitem != $1) {
    window -c @wowhead
    window -dBdpow0 +dL @wowhead $calc($mouse.dx +15) $calc($mouse.dy -215) 300 200
    drawtext -p @wowhead 0 5 5 Loading...
    join $chan
    sockclose itemsocket
    sockopen itemsocket www.wowhead.com 80
    sockmark itemsocket $remove($1,http://www.wowhead.com/?item=,<,>.) echo 4 -a
  }
  set %lastitem $1
  set -u3 %cooldown 1
  return 1
}
on *:SOCKOPEN:itemsocket:{
  sockwrite -nt $sockname GET /?item= $+ $gettok($sock($sockname).mark,1,32) $+ &xml HTTP/1.0
  sockwrite -nt $sockname Host: www.wowhead.com $+ $crlf $+ $crlf
  unset %data %switch
}
on *:sockread:itemsocket:{
  if ($sockerr > 0) return
  :nextread
  sockread -f %temp
  if ($sockbr == 0) return
  inc %switch 1
  if (%switch > 11) {
    set -u3 %data %data $+ %temp
    if (Item not Found! isin %data) { sockclose $sockname }
  }
  goto nextread
}
on *:sockclose:itemsocket:{
  var %startpos = $calc($pos(%data,htmlTooltip,1) +12)
  var %len = $calc($pos(%data,htmlTooltip,2) - %startpos -5)
  var %exploded,%x = $regsub($mid(%data,%startpos,%len),m/<!--[^-]+-->|<\/?(a|span|small)[^>]*>/g,$null,%exploded)
  var %exploded = $replace(%exploded,>,> $+ $chr(160))
  var %exploded = $striptags(%exploded)
  var %exploded = $replace(%exploded,$chr(40) $+ $chr(160),$chr(40),L $+ $chr(160),L,Classes: $+ $str($chr(1260),2),Classes: $+ $chr(32),&lt;,<,&gt;,>)
  tokenize 160 %exploded
  drawfill -r @wowhead 1315860 1315860 0 0 300 200
  var %this = 0, %total = $0
  while (%this < %total) {
    inc %this 1
    drawtext -rp @wowhead 16777215 5 $calc((%this * 15) - 10) $($ $+ %this,2)
  }
}
alias striptags { var %x,%y = $regsub($1-,/(<[^>]+>)/g,$null,%x) | return $replace($remove(%x,$chr(9)),&nbsp;,$chr(32),&quot;,") }