on ^1:HOTLINK:*item=*:#:{
  .timerwh off
  .timerwh 1 3 window -c @wowhead
  window -dBdpow0 +dL @wowhead $calc($mouse.dx +15) $calc($mouse.dy -215) 300 200
  if (http:// isin $1) && (!%cooldown) {
    window -c @wowhead
    window -dBdpow0 +dL @wowhead $calc($mouse.dx +15) $calc($mouse.dy -215) 300 200
    drawfill -r @wowhead 1315860 1315860 0 0 300 200
    drawtext -p @wowhead 0 5 5 Loading...
    join $chan
    sockclose itemsocket
    sockopen itemsocket www.wowhead.com 80
    sockmark itemsocket $remove($1,http://www.wowhead.com/?item=,<,>.) echo 4 -a
    ;if ($dialog(wowhead)) { dialog -x wowhead }
    ;dialog -m wowhead wowhead -1 -1 150 200
  }
  set -u3 %cooldown 1
  return 1
}
on *:SOCKOPEN:itemsocket:{
  sockwrite -nt $sockname GET /?item= $+ $gettok($sock($sockname).mark,1,32) $+ &xml HTTP/1.0
  sockwrite -nt $sockname Host: www.wowhead.com $+ $crlf $+ $crlf
  unset %data %switch
}
on *:sockread:itemsocket:{
  if ($sockerr > 0) return
  :nextread
  sockread -f %temp
  if ($sockbr == 0) return
  inc %switch 1
  if (%switch > 11) {
    set -u3 %data %data $+ %temp
    if (Item not Found! isin %data) {
      ;did -r wowhead 1
      ;did -a wowhead 1 No result for07 $gettok($sock($sockname).mark,1,32)
      sockclose $sockname
    }
  }
  goto nextread
}
on *:sockclose:itemsocket:{
  var %startpos = $calc($pos(%data,htmlTooltip,1) +12)
  var %len = $calc($pos(%data,htmlTooltip,2) - %startpos -5)
  var %exploded,%x = $regsub($mid(%data,%startpos,%len),m/<!--[^-]+-->|<\/?(a|span|small)[^>]*>/g,$null,%exploded)
  var %exploded = $replace(%exploded,>,> $+ $chr(160))
  var %exploded = $striptags(%exploded)
  var %exploded = $replace(%exploded,$chr(40) $+ $chr(160),$chr(40),L $+ $chr(160),L,Classes: $+ $str($chr(1260),2),Classes: $+ $chr(32),&lt;,<,&gt;,>)
  ;did -r wowhead 1
  tokenize 160 %exploded
  drawfill -r @wowhead 1315860 1315860 0 0 300 200
  var %this = 0, %total = $0
  while (%this < %total) {
    inc %this 1
    ; $gettok($sock($sockname).mark,2-,32) $($ $+ %this,2) ; This line should also be uncommented to make the script public. This functionality will be removed in a later version.
    drawtext -rp @wowhead 16777215 5 $calc((%this * 15) + 5) $($ $+ %this,2)
    ;did -a wowhead 1 $($ $+ %this,2) $crlf
  }
}
alias striptags { var %x,%y = $regsub($1-,/(<[^>]+>)/g,$null,%x) | return $replace($remove(%x,$chr(9)),&nbsp;,$chr(32),&quot;,") }
dialog wowhead {
  title "mIRC: Powered by Wowhead v0.1 (by spling)"
  size -1 -1 150 200
  option dbu

  edit "Loading..", 1, -1 -1 152 202,read,multi,rich
}