on ^1:HOTLINK:*item=*:#wow:{
  if (http:// isin $1) && (!%cooldown) {
    set -u1 %cooldown 3
    sockclose itemsocket
    sockopen itemsocket www.wowhead.com 80
    sockmark itemsocket $remove($1,http://www.wowhead.com/?item=,<,>.) echo 4 -a
    if ($dialog(wowhead)) { dialog -x wowhead }
    dialog -m wowhead wowhead -1 -1 150 200
  }
  return
}
/*
Uncommenting this area can make this script public. Best not to uncomment if you cannot bypass flood queueing.
on *:TEXT:!wh *:#wowhead:{
  if ($2) && (!%cd) {
    set -u3 %cd 1
    go $replace($2-,$chr(32),+)
  }
}
alias go {
  msg #wowhead Looking up item07 $1 (3s cooldown!)...
  sockopen itemsocket www.wowhead.com 80
  sockmark itemsocket $1 msg #wowhead
}
*/
on *:SOCKOPEN:itemsocket:{
  sockwrite -nt $sockname GET /?item= $+ $gettok($sock($sockname).mark,1,32) $+ &xml HTTP/1.0
  sockwrite -nt $sockname Host: www.wowhead.com $+ $crlf $+ $crlf
  unset %data %switch
}
on *:sockread:itemsocket:{
  if ($sockerr > 0) return
  :nextread
  sockread -f %temp
  if ($sockbr == 0) return
  inc %switch 1
  if (%switch > 11) {
    set -u3 %data %data $+ %temp
    if (Item not Found! isin %data) {
      did -r wowhead 1
      did -a wowhead 1 No result for07 $gettok($sock($sockname).mark,1,32)
      sockclose $sockname
    }
  }
  goto nextread
}
on *:sockclose:itemsocket:{
  var %startpos = $calc($pos(%data,htmlTooltip,1) +12)
  var %len = $calc($pos(%data,htmlTooltip,2) - %startpos -5)
  var %exploded,%x = $regsub($mid(%data,%startpos,%len),m/<!--[^-]+-->|<\/?(a|span|small)[^>]*>/g,$null,%exploded)
  var %exploded = $replace(%exploded,>,> )
  var %exploded = $striptags(%exploded)
  var %exploded = $replace(%exploded,$chr(40) $+ $chr(160),$chr(40),L $+ $chr(160),L,Classes:  ,Classes: $+ $chr(32),&lt;,<,&gt;,>)
  did -r wowhead 1
  tokenize 160 %exploded
  var %this = 0, %total = $0
  while (%this < %total) {
    inc %this 1
    ; $gettok($sock($sockname).mark,2-,32) $($ $+ %this,2) ; This line should also be uncommented to make the script public. This functionality will be removed in a later version.
    did -a wowhead 1 $($ $+ %this,2) $crlf
  }
}
alias striptags { var %x,%y = $regsub($1-,/(<[^>]+>)/g,$null,%x) | return $replace($remove(%x,$chr(9)),&nbsp;,$chr(32),&quot;,") }
dialog wowhead {
  title "mIRC: Powered by Wowhead v0.1 (by spling)"
  size -1 -1 150 200
  option dbu

  edit "Loading..", 1, -1 -1 152 202,read,multi,rich
}